# Description: Build configuration for the GeoDMA Feature Extraction Module
#
#  Author: Raian Vargas Maretto <raian@dpi.inpe.br>
#          Thales Sehn Korting <tkorting@dpi.inpe.br>
#          Emiliano Ferreira Castejon <castejon@dpi.inpe.br>
#

# Includes
include_directories(${Boost_INCLUDE_DIRS})
include_directories(${terralib_INCLUDE_DIRS})
include_directories(${CGAL_INCLUDE_DIRS})

#Set include directories location
#include_directories(${GEODMA_SRC_DIR}/geodmalib/featureextraction
#                    ${GEODMA_SRC_DIR}/geodmalib/common
#)
include_directories(${GEODMA_SRC_DIR})

if(WIN32)
  add_definitions(-DGDMAFTEDLL)
endif()

# Source and Header files
file(GLOB GEODMA_FTE_SRCS ${GEODMA_SRC_DIR}/geodmalib/featureextraction/*.cpp)
file(GLOB GEODMA_FTE_HDRS ${GEODMA_SRC_DIR}/geodmalib/featureextraction/*.hpp)

# Creating source groups for IDEs
source_group("Source Files"  FILES ${GEODMA_FTE_SRCS})
source_group("Header Files"  FILES ${GEODMA_FTE_HDRS})

# Setting Dependencies
set(GEODMA_FTE_LIB_DEPENDENCIES ${CMAKE_THREAD_LIBS_INIT}
                                ${Boost_SYSTEM_LIBRARY}
                                ${Boost_FILESYSTEM_LIBRARY}
                                ${Boost_CHRONO_LIBRARY}
                                ${VTK_LIBRARIES}
                                terralib_mod_raster
                                terralib_mod_common
                                terralib_mod_rp
                                terralib_mod_geometry
                                terralib_mod_dataaccess
                                terralib_mod_statistics_core
                                terralib_mod_memory
                                geodma_mod_common
)

add_library(geodma_mod_featextraction SHARED ${GEODMA_FTE_SRCS} ${GEODMA_FTE_HDRS})

target_link_libraries(geodma_mod_featextraction ${GEODMA_FTE_LIB_DEPENDENCIES})

# set_property(TARGET geodma_mod_featextraction PROPERTY DEBUG_POSTFIX _d)

if(GEODMA_SOURCE_VERIFY_ENABLED)
    add_style_check_target(geodma_mod_featextraction "${GEODMA_FTE_SRCS};${GEODMA_FTE_HDRS}")
endif()

set_target_properties(geodma_mod_featextraction
                      PROPERTIES VERSION ${GEODMA_VERSION_MAJOR}.${GEODMA_VERSION_MINOR}
                                 SOVERSION ${GEODMA_VERSION_MAJOR}.${GEODMA_VERSION_MINOR})
                                 #INSTALL_NAME_DIR "@executable_path/../lib")

if(NOT GEODMA_TRACK_3RDPARTY_DEPENDENCIES_ENABLED)

    install(TARGETS geodma_mod_featextraction
            EXPORT geodma-targets
            RUNTIME DESTINATION ${GEODMA_DESTINATION_RUNTIME} COMPONENT runtime
            LIBRARY DESTINATION ${GEODMA_DESTINATION_LIBRARY} COMPONENT runtime
            ARCHIVE DESTINATION ${GEODMA_DESTINATION_ARCHIVE} COMPONENT runtime)
endif()

install(FILES ${GEODMA_FTE_HDRS}
        DESTINATION ${GEODMA_DESTINATION_HEADERS}/geodma/featureextraction
        COMPONENT devel)

export(TARGETS geodma_mod_featextraction APPEND FILE ${CMAKE_BINARY_DIR}/geodma-exports.cmake)
