# Description: Build configuration for the GeoDMA Task Processing Module
#
#  Author: Raian Vargas Maretto <raian@dpi.inpe.br>
#          Thales Sehn Korting <tkorting@dpi.inpe.br>
#          Emiliano Ferreira Castejon <castejon@dpi.inpe.br>
#

# Includes
include_directories(${Boost_INCLUDE_DIRS})
include_directories(${terralib_INCLUDE_DIRS})

#Set include directories location
#include_directories(${GEODMA_SRC_DIR}/lib/common)
include_directories(${GEODMA_SRC_DIR})

if(WIN32)
  add_definitions(-DGDMATASKPROCESSINGDLL)
endif()

# Source and Header files
file(GLOB GEODMA_TP_SRCS ${GEODMA_SRC_DIR}/geodmalib/taskprocessing/*.cpp)
file(GLOB GEODMA_TP_HDRS ${GEODMA_SRC_DIR}/geodmalib/taskprocessing/*.hpp)

# Creating source groups for IDEs
source_group("Source Files"  FILES ${GEODMA_TP_SRCS})
source_group("Header Files"  FILES ${GEODMA_TP_HDRS})

# Setting Dependencies
set(GEODMA_TP_LIB_DEPENDENCIES ${CMAKE_THREAD_LIBS_INIT}
                               terralib_mod_common
                               geodma_mod_common
)

add_library(geodma_mod_taskprocessing SHARED ${GEODMA_TP_SRCS} ${GEODMA_TP_HDRS})

target_link_libraries(geodma_mod_taskprocessing ${GEODMA_TP_LIB_DEPENDENCIES})

if(GEODMA_SOURCE_VERIFY_ENABLED)
    add_style_check_target(geodma_mod_taskprocessing "${GEODMA_TP_SRCS};${GEODMA_TP_HDRS}")
endif()

set_target_properties(geodma_mod_taskprocessing
                      PROPERTIES VERSION ${GEODMA_VERSION_MAJOR}.${GEODMA_VERSION_MINOR}
                                 SOVERSION ${GEODMA_VERSION_MAJOR}.${GEODMA_VERSION_MINOR})

if(NOT GEODMA_TRACK_3RDPARTY_DEPENDENCIES_ENABLED)
    install(TARGETS geodma_mod_taskprocessing
            EXPORT geodma-targets
            RUNTIME DESTINATION ${GEODMA_DESTINATION_RUNTIME} COMPONENT runtime
            LIBRARY DESTINATION ${GEODMA_DESTINATION_LIBRARY} COMPONENT runtime
            ARCHIVE DESTINATION ${GEODMA_DESTINATION_ARCHIVE} COMPONENT runtime)
endif()

install(FILES ${GEODMA_TP_HDRS}
        DESTINATION ${GEODMA_DESTINATION_HEADERS}/geodma/taskprocessing
        COMPONENT devel)

export(TARGETS geodma_mod_taskprocessing APPEND FILE ${CMAKE_BINARY_DIR}/geodma-exports.cmake)
